삽질 마니아 TylorSTYLE™ 의 공사장

 터치 패널쪽
| # # # #|
| # # # #|
| # # # #|
| | | | | |
  1 2 3 4
 터치 컨트롤러 쪽

{ 셀 갈구리질 }
function MyShellHook(Code : Integer; wParam : WPARAM; lParam : LPARAM) : LongInt; stdcall;
var
  Buff : array [0..255] of Char;
  s : String;
begin
  { 파일에 저장된 훅핸들을 읽어온다. }
  if HShellHook = 0 then
    ReadData;

  { 윈도우의 생성과 소멸만 괴롭힌다. 자세한 내용은 도움말을 참조할 것. }
  if (code = HSHELL_WINDOWCREATED) or (code = HSHELL_WINDOWDESTROYED) then
  begin
    { 윈도우의 클래스명을 읽어온다. Code값이 위의 두개의 값일 경우, wParam은 윈도우의 핸들값이 된다. }
    GetClassName(wParam, Buff, SizeOf(Buff));

    { 클래스명이 노트패드라면 메시지박스 보여주기. }

    if Buff = 'Notepad' then
    begin
      if (code = HSHELL_WINDOWCREATED) then
        S := '메모장이 실행되는구만요~!'
      else
        S := '메모장이 끝났구만요~!';
      MessageBox(0,PChar(S),'Hook Message',0);
    end;
end;
{ 다음 훅체인 호출 }
Result := CallNextHookEx(HShellHook, Code, wParam, lParam);
end;

제가 작성했던 코드에서는 이전 포스트의 프로세스 아이디로 윈도우 핸들을 얻는 코드를 통해 윈도우 핸들은 얻은 뒤 후킹 DLL 로 핸들 값을 넘겨 위 코드를 이용해 해당 프로그램이 죽는지 사는지 감시하도록 했습니다. (아래 코드 첨부)

function MyShellHook(Code : Integer; wParam : WPARAM; lParam : LPARAM) : LongInt; stdcall;
var
  Buff : array [0..255] of Char;
  clsName : array [0..255] of Char;
begin
  if HookData.ApplicationHandle = 0 then // HookData.ApplicationHandle 은 제가 만든 훅 핸들 보관용 구조체입니다.
    ReadData;

  if (code = HSHELL_WINDOWCREATED) or (code = HSHELL_WINDOWDESTROYED) then
  begin
    GetClassName(wParam, Buff, SizeOf(Buff));
    GetClassName(HookData.hApp, clsName, SizeOf(clsName)); // HookData.hApp 에는 감시할 프로그램의 핸들이 들어있습니다.

    if strPAS(Buff) = strPAS(clsName) then
    begin
      if (code = HSHELL_WINDOWCREATED) then
      begin
        SendMessage(HookData.ShellHandle, WM_USER + 4, 0, 1);
      end else
      begin
        SendMessage(HookData.ShellHandle, WM_USER + 4, 0, 0);
      end;
    end;
  end;
  { 다음 훅체인 호출 }
  Result := CallNextHookEx(HookData.ApplicationHandle, Code, wParam, lParam);
end;

 이 코드에서는 클래스명 비교부분에 strPAS 함수를 사용하여 비교하도록 하였습니다.
 민성기님 코드의 경우 비교문 우측에 'Notepad' 라는 String 문자열이 있어 좌측 Char 배열을 컴파일러가 비교를 위해 자동 형변환을 하도록 했지만 위 코드에서는 비교문 양쪽 모두 Char 배열이 되어 문자열로 비교하지 않게 됩니다.
 strPAS를 통해 String 으로 변환하여 비교하면 문제없이 처리가 됩니다.

 최근 개인적으로 이것 저것 신경쓸 것 도 많고, 바쁘기도 해서, TSGMapsGPS 마무리 작업도 몇 개월 째 진행도 못하고 블로그는 방치 상태입니다. 흐헝흐흥 ㅠ.ㅠ

 블로그의 정전을 깨기 위해 오랜만에 작업하면서 정리한(?) 코드를 올립니다.

 이 코드는 볼랜드 포럼의 '프로세스 아이디로 윈도우 핸들 얻기' 라는 글의(아래 링크) C 코드를 Delphi 용으로 조금 변형한 코드입니다.
http://cbuilder.borlandforum.com/impboard/impboard.dll?action=read&db=bcb_tip&no=895

함수 소개 :
 실행 파일의 경로를 인자로 함수를 호출하면 실행파일 실행 후 리턴값으로 실행된 파일의 Window Handle 을 반환합니다.

Function TForm1.ApplicationStart(ApplicationPath : String) : THandle;
  // 함수 내 내부 함수.
  function GetWinHandle(pid : Cardinal): THandle; // 프로세스 아이디로 윈도우 핸들 얻기
  var
    tempHwnd : THandle;
    idProc : Cardinal;
  begin
    result := 0;

    tempHwnd := FindWindow(NIL, NIL); // 최상위 윈도우 핸들 찾기

    while( tempHwnd <> 0 ) do
    begin
      if( GetParent(tempHwnd) = 0 ) then // 최상위 핸들인지 체크, 버튼 등도 핸들을 가질 수 있으므로 무시하기 위해
      begin

        GetWindowThreadProcessId( tempHwnd, idProc );

        //if( pid = ProcIDFromWnd(tempHwnd) ) then
        if (pid = idProc) then
        begin
          result := tempHwnd;
          break;
        end;
      end;
      tempHwnd := GetWindow(tempHwnd, GW_HWNDNEXT); // 다음 윈도우 핸들 찾기
    end;

  end;

var
  SInfo: TStartupInfo;
  PInfo: TProcessInformation;
begin
  Result := 0;

  if (ApplicationPath <> '') then
  begin
    if not FileExists(ApplicationPath) then // 파일의 존재 여부 확인.
    begin
      exit;
    end;
  end;

  FillChar(SInfo, SizeOf(SInfo), 0);
  SInfo.cb := SizeOf(SInfo);
  if CreateProcess(nil, PChar(ApplicationPath), nil, nil, False, NORMAL_PRIORITY_CLASS, nil, nil, SInfo, PInfo) then // 프로그램 실행.
  begin
    CloseHandle(PInfo.hThread);
    WaitForInputIdle(PInfo.hProcess, INFINITE);
    Result := GetWinHandle(PInfo.dwProcessId);
    CloseHandle(PInfo.hProcess);

  end;
end;